More about plots:
    I. Options for nicer graphical output
   II. Plots with Error Bars
  III. Log Plots 
  IV. Exporting graphics

Making pretty plots

Standard Output of Plot and ListPlot commands

plotA =Plot[{Sin[x^2],Sin[x^3]},{x,0,2}]

data = Table[{i,i^2/4},{i,0,2,.2}];
plotB = ListPlot[data]

Show[plotA, plotB]

No axes labels
Font size too small for publication
Data points too small
No frame (not always desired)
Lines not very thick
Range may not be what you want.

Setting some options for plots

This can be done within individual plots, or globally as below.

Font Selection

SetOptions[Plot,BaseStyle->{FontFamily->"Times",FontSize->18}];

Point Size

SetOptions[ListPlot,PlotStyle->PointSize[0.02]];

Options for nicer graphs

plotC =Plot[{Sin[x^2],Sin[x^3]},{x,0,2},Frame->True,PlotStyle->{{Red,Thick},Blue},FrameLabel->{x,f[x]},PlotRange->{-1.2,1.2}];
plotD= ListPlot[data];
plotBoth = Show[plotC,plotD]

Plots with Error Bars

Important : To get ErrorListPlot working you need to first use the Needs[ ...] command

ErrorListPlot works like ListPlot, but it assumes the last element for each point is the error bar, i.e, points are {x,y,σ}.

Needs["ErrorBarPlots`"]

Clear[data];
data = {{1,1,0.5},{2,4,0.9},{3,9,0.3}};
ErrorListPlot[data,PlotStyle->PointSize[.017],PlotRange->{{0,4},{0,10}}]

Plots with Logarithmic Scales

Consider the illustrated data for the output of a low - pass RC filter as a function of frequency.

rcData={{13,9.84},{127,9.68},{261,"9,36"},{639,8.32},{1198,6.4},{2275,4.04},{6706,1.48},{14130,0.712},{23000,0.428},{68500,0.142},{122200,0.08},{220000,0.048}};

SetOptions[ListLogLogPlot, BaseStyle -> {FontFamily -> "Times", FontSize -> 16}];
SetOptions[ListPlot, BaseStyle -> {FontFamily -> "Times", FontSize -> 16}];

ListPlot[rcData, Frame -> True, FrameLabel -> {f, V}, PlotStyle -> PointSize[0.015]]

As those of you who have taken Electronics may remember, the characteristics of the filter are revealed in a log - log plot.

ListPlot[Log[rcData],PlotStyle->PointSize[0.015],Frame->True,PlotRange->{{2,13},{3,-3.5}},FrameLabel->{Log[f],Log[V]}]

The log - log plot above is not a viewer - friendly way to present the data.  Consider the 
question : "What is the breakpoint frequency of the filter?"  This is not readily  apparent from the graph.  Log plots should be presented with logarithmic scales, with the labels corresponding the frequency, not the log of the frequency.

llData=ListLogLogPlot[rcData,PlotStyle->PointSize[0.015],Frame->True,PlotRange->{{1,200000},{0.1,12}},FrameLabel->{f,V}]

Saving graphs to files

?Export

(I' m not sure why, but in previous versions of Mathematica I had to execute the following command twice if you choose eps as the output format.)

Export["graph.pdf",plotBoth]